#!ipxe

### VARIABLES #############################################################################################
set http-root     http://boot.bitbull.ch
set memdisk-url   ${http-root}/syslinux/memdisk

set rcd-iso-url ${http-root}/iso/systemrescue-11.00-amd64.iso

set clonezilla-iso-url ${http-root}/iso/clonezilla-live-3.1.2-9-amd64.iso

set slitaz-iso-url http://download.tuxfamily.org/slitaz/iso/latest/slitaz-rolling-core64.iso

set rocky9-ks-url ${http-root}/ks/rocky9_minimal.cfg
set rocky9-cis-l1-ks-url ${http-root}/ks/ssg-rhel9-cis_server_l1-ks.cfg
set rocky9-cis-l2-ks-url ${http-root}/ks/ssg-rhel9-cis-ks.cfg

set rocky9-os-url http://dl.rockylinux.org/pub/rocky/9/BaseOS/x86_64/os

### MENU CONFIG ##########################################################################################
set menu-timeout 30000
set menu-default exit
set submenu-timeout ${menu-timeout}
set submenu-default start

:start
menu =============== BITBULL iPXE BOOT MENU ===============
item --gap --                   ---------------------------- KICKSTART root/redhat -----------------------
item            rel9_ks             Install Red Hat Linux 9   - Minimal Setup from Foreman
item --gap --                   ---------------------------- KICKSTART root/redhat -----------------------
item            rocky9_ks           Install Rocky Linux 9   - Minimal Setup
item            rocky9_cis_l1_ks    Install Rocky Linux 9 - CIS profile (Level 1 - Server)
item            rocky9_cis_l2_ks    Install Rocky Linux 9 - CIS profile (Level 2 - Server)
item --gap --                   ---------------------------- Installers ----------------------------------
item            rocky9_inst         Install Rocky Linux 9
item            ubuntu2004_inst     Install Ubuntu 20.04
item            hvst_inst           Install Rancher Harvester 1.2.1 Release
item --gap --                   ------------------------- Sub Menus --------------------------------------
item            tools                   Rescue Tools and more iPXE Settings
item --gap --                   --------------------------------------------------------------------------
item --key x    exit                    Exit iPXE and continue BIOS boot
choose --timeout ${menu-timeout} --default ${menu-default} selected || goto cancel
set menu-timeout 0
goto ${selected}

:tools
menu ========== BITBULL iPXE TOOLS + SETTINGS MENU ==========
item --gap --                   --------------------------------------------------------------------------
item            start                   Back to main Menu               
item --key x    exit                    Exit iPXE and continue BIOS boot
item            shell                   Drop to iPXE shell
item            reboot                  Reboot
item --gap --                   ---------------------- Live Operating Systems ----------------------------
item --key r    systemrescue_live       Systemrescue CD
item --key c    clonezilla_live         CloneZilla Live CD
item            rocky9_resc             Rescue Rocky Linux 9
item            slitaz_live             Slitaz Live CD
choose --timeout ${submenu-timeout} --default ${submenu-default} selected || goto cancel
set submenu-timeout 0
goto ${selected}

:cancel
echo You cancelled the menu, dropping you to a shell

:shell
echo Type 'exit' to get the back to the menu
shell
set menu-timeout 0
set submenu-timeout 0
goto start

:reboot
reboot

:exit
exit

### DIGANOSE ENTRIES ##################################################################################
:systemrescue_live
initrd ${rcd-iso-url}
chain ${memdisk-url} iso || goto start

:clonezilla_live
sanboot ${clonezilla-iso-url} || goto start

:slitaz_live
sanboot ${slitaz-iso-url} || goto start

############################ ALMA LINUX 9 ##################################################
:rocky9_inst
kernel ${rocky9-os-url}/images/pxeboot/vmlinuz initrd=initrd.img inst.repo=${rocky9-os-url}
initrd ${rocky9-os-url}/images/pxeboot/initrd.img
boot || goto start

:rocky9_resc
kernel ${rocky9-os-url}/images/pxeboot/vmlinuz initrd=initrd.img inst.repo=${rocky9-os-url} inst.rescue
initrd ${rocky9-os-url}/images/pxeboot/initrd.img
boot || goto start


:rel9_ks
kernel http://boot.bitbull.ch/el9/vmlinuz initrd=initrd.img inst.repo=https://satellite.bitbull.ch/pulp/content/BITBULL/Library/content/dist/rhel9/9.4/x86_64/baseos/kickstart inst.ks=https://boot.bitbull.ch/el9/ks.cfg
initrd http://boot.bitbull.ch/el9/initrd.img
boot || goto start

:rocky9_ks
kernel ${rocky9-os-url}/images/pxeboot/vmlinuz initrd=initrd.img inst.repo=${rocky9-os-url} inst.ks=${rocky9-ks-url}
initrd ${rocky9-os-url}/images/pxeboot/initrd.img
boot || goto start

:rocky9_cis_l1_ks
kernel ${rocky9-os-url}/images/pxeboot/vmlinuz initrd=initrd.img inst.repo=${rocky9-os-url} inst.ks=${rocky9-cis-l1-ks-url}
initrd ${rocky9-os-url}/images/pxeboot/initrd.img
boot || goto start

:rocky9_cis_l2_ks
kernel ${rocky9-os-url}/images/pxeboot/vmlinuz initrd=initrd.img inst.repo=${rocky9-os-url} inst.ks=${rocky9-cis-l2-ks-url}
initrd ${rocky9-os-url}/images/pxeboot/initrd.img
boot || goto start

############################ UBUNTU LINUX 20.04 #############################################
:ubuntu2004_inst
set dist-root http://mirror.init7.net/ubuntu/dists/focal/main
kernel ${dist-root}/installer-amd64/current/legacy-images/netboot/ubuntu-installer/amd64/linux
initrd ${dist-root}/installer-amd64/current/legacy-images/netboot/ubuntu-installer/amd64/initrd.gz
imgargs linux initrd=initrd.gz boot=casper ip=dhcp
boot || goto start

############################ HARVESTER MASTER RELEASE #######################################
:hvst_inst
set dist-ver v1.2.1
set dist-root ${http-root}/hvst/${dist-ver}
kernel ${dist-root}/harvester-${dist-ver}-vmlinuz-amd64 ip=dhcp rd.cos.disable rd.noverifyssl net.ifnames=1 root=live:${dist-root}/harvester-${dist-ver}-rootfs-amd64.squashfs console=tty1 harvester.install.automatic=false harvester.install.config_url=${dist-root}/version.yaml
initrd ${dist-root}/harvester-${dist-ver}-initrd-amd64
boot || goto start